[文本处理] [已解决]三个随机数文本的行字符，组合为名字的批处理？

zzz19760225

1.txt

赵
钱
孙
复制代码

2.txt

建
立
卫
复制代码

3.txt

国
家
星
复制代码

抄写的77七批处理
http://www.bathome.net/viewthread.php?tid=66385&highlight=
早晨.bat

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('type "早晨.txt"') do (
	set /a n+=1
	set "#!n!=%%a"
)
set /a m=%random% %% %n% + 1 
echo !#%m%!
endlocal
pause
复制代码

改为
姓名.bat

@echo off
setlocal enabledelayedexpansion
:0
for /f "delims=" %%a in ('type "1.txt"') do (
for /f "delims=" %%b in ('type "2.txt"') do (
for /f "delims=" %%c in ('type "3.txt"') do (
	set /a n+=1
	set "#!n!=%%a%%b%%c"
)))
set /a m=%random% %% %n% + 1 
echo !#%m%!
pause
goto:0
endlocal
pause

显

孙立国
请按任意键继续. . .
孙建家
请按任意键继续. . .
赵立星
请按任意键继续. . .
复制代码

但是这种随机叠加的批处理太慢了，求加快速度的批处理。

aloha20200628

回复 1# zzz19760225

@echo off &setlocal enabledelayedexpansion
set "n1=0" &for /f "delims=" %%v in (1.txt) do set/a "n1+=1"&set "_1!n1!=%%v"
set "n2=0" &for /f "delims=" %%v in (2.txt) do set/a "n2+=1"&set "_2!n2!=%%v"
set "n3=0" &for /f "delims=" %%v in (3.txt) do set/a "n3+=1"&set "_3!n3!=%%v"
:#loop#
   set/a a=!random!%%!n1!+1
   set/a b=!random!%%!n2!+1
   set/a c=!random!%%!n3!+1
   echo,!_1%a%!!_2%b%!!_3%c%!
   set/p "loop=直接回车键》下一个 其余键》退出："
   if defined loop (exit/b) else (goto #loop#)
复制代码

Five66

将第3行的
:0
移到第9行的
)))
之后 ,这样就不用每次goto都读取并设置了

zzz19760225

感谢两位解答。
请问，如果要调用的话，需要怎么写啊
我这写的不能正常运行，用通义问的结果也无法正常运行，都是系统找不到for开始三个字。

@echo off
:0
set /p nc=:
if exist %nc% (set a=%nc%) else (call:1)
echo:%a%
goto:0
pause&exit

:1
setlocal enabledelayedexpansion
set "n1=1" &for /f "delims=," %%v in (张,王,赵,李,钱) do set/a "n1+=1"&set "_1!n1!=%%v"
set "n2=1" &for /f "delims=," %%v in (中,华,富,强) do set/a "n2+=1"&set "_2!n2!=%%v"
set "n3=1" &for /f "delims=," %%v in (万,世,太,平) do set/a "n3+=1"&set "_3!n3!=%%v"
   set/a a=%random%%%!n1!+1
   set/a b=%random%%%!n2!+1
   set/a c=%random%%%!n3!+1
   set z=!_1%a%!!_2%b%!!_3%c%!
set a=!z!
exit/b
显
:1
系统找不到文件 张。
系统找不到文件 中。
系统找不到文件 万。
:
复制代码

aloha20200628

回复 4# zzz19760225

参考以下版本修正你的4楼代码...

@echo off &setlocal enabledelayedexpansion
:#l1
 call :#l2
 echo,!z!
 set/p "loop=直接回车键》下一个 其余键》退出："
 if defined loop (exit/b) else (goto #l1)

:#l2
 set "n1=0" &for %%v in (张,王,赵,李,钱) do set/a "n1+=1"&set "_1!n1!=%%v"
 set "n2=0" &for %%v in (中,华,富,强) do set/a "n2+=1"&set "_2!n2!=%%v"
 set "n3=0" &for %%v in (万,世,太,平) do set/a "n3+=1"&set "_3!n3!=%%v"
 set/a a=!random!%%!n1!+1
 set/a b=!random!%%!n2!+1
 set/a c=!random!%%!n3!+1
 set "z=!_1%a%!!_2%b%!!_3%c%!"
 exit/b
复制代码

zzz19760225

回复 5# aloha20200628

@echo off
set a=1
echo:1:%a%
setlocal enabledelayedexpansion
set a=2
echo:2:!a!
endlocal
echo:3:!a!
echo:4:%a%
pause&exit
显
1:1
2:2
3:!a!
4:1
请按任意键继续. . .
复制代码

请问大佬，变量延迟的局部变量值echo:2:!a!，如何转化为全局环境变量值呢？

aloha20200628

回复 6# zzz19760225

运行以下版本可体会 ‘!var!变量如何续命给%var%变量’ ...

@echo off
set a=1
echo,1:a=%a%
setlocal enabledelayedexpansion
set a=2
echo,2:a=!a!,%a%
endlocal &set b=%a%
echo,4:a=%a%,b=%b%
pause&exit/b
复制代码